Following a particular atom over a trajectory

we use the code below from Andrew Dalke and Axel Kohlmeyer
copy the tcl script to the relevant directory call it traj_path.tcl
open your trajectory in VMD
you probably want to play around with the visualisation options
use Mouse:Query to identify a specific molecule
look on the VMD terminal screen and identify the residue you want to follow
then you need to "set" this as the molecule to follow
in the VMD terminal screen type name [atomselect top "resid x"]

where name is the name you are giving to this molecule/residue to follow

and where x is the residue ID number

see below for an example where I have used emim as the name and residue 1

Info) picked atom: 
Info) ------------
Info) molecule id: 2
Info) trajectory frame: 5
Info) name: CR
Info) type: CR
Info) index: 837
Info) residue: 73
Info) resname: 
Info) resid: 1
Info) chain: X
Info) segname: 
Info) x: 16.814091
Info) y: -8.572735
Info) z: 21.076117
set emim [atomselect top "resid 1"]
atomselect0
vmd >

now you need to "import" the tcl script into VMD so type source traj_path.tcl
then you want to type traj_path $name [atomselect top "residue x"]
below is an example of a successfull run

>Main< (masahiro) 54 % source traj_path.tcl
>Main< (masahiro) 55 % set emim [atomselect top "residue 309"]
atomselect0
>Main< (masahiro) 56 % traj_path $emim red
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206
>Main< (masahiro) 57 % set fsi [atomselect top "residue 552"]
atomselect1
>Main< (masahiro) 58 % traj_path $fsi red
208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413
>Main< (masahiro) 59 %

# Draws the path of the center of mass of a selection through an animation
# Andrew Dalke <dalke@ks.uiuc.edu>
# Axel Kohlmeyer <axel.kohlmeyer@rub.de&gt
#
#Procedures:
# trajectory_path selection {color blue} {linewidth 1} {update 0}
# -- follows the center of mass of the given selection.  
# 'color' is a solid color, or "scale" for a color scale,
# 'update' toggles calling "$selection update"
# 'linewidth' is the width of the line drawn.
#
#Description:
# For each step in the animation, the center of mass of the selection is
# calculated.  A line connecting the successive center of mass coordinates
# is then added to the molecule id of the selection. 
#
# color
# The color is a solid color (default is blue) or they are mapped to the 
# color scale from lowest (= first trajectory frame) to highest (= last 
# trajectory frame).
# 
# updated?
# The third argument decides (0 = no, 1 = yes) whether the selection
# is updated during the course of following the C.O.M. (default is no).
# The procedure returns the graphics ids of the drawn objects.
#
#Example:
# set water [atomselect top "resid 5243"]
# trajectory_path $water scale
#
# to follow the solvation shell around an atom.
# set solv  [atomselect top "water and exwithin 3.8 of index 199"]
# trajectory_path $solv yellow 3 1

proc trajectory_path {selection {color blue} {linewidth 2} {update 1}} {

 # save the current selection frame number and get the molecule id.
 set sel_frame [$selection frame]
 set gr_mol [$selection molindex]

 # make the list of coordinates
 set num_frames [molinfo $gr_mol get numframes]
 set coords {}
 for {set i 0} {$i < $num_frames} {incr i} {
   $selection frame $i
   if {$update} { $selection update }
   # compute the center of mass and save it on the list
   lappend coords [measure center $selection weight mass]
 }
 ##### now make the graphics and store the respective graphic ids in a list.
 set gr_list {}
 set coords [lassign $coords prev]

 # use the color scale?
 if {$color == "scale"} {
   set count 0
   incr num_frames
   foreach coord $coords {
     set color [expr [colorinfo num] + int([colorinfo max] * ($count + 0.0) / ($num_frames + 0.0))]
     graphics $gr_mol color $color
     lappend gr_list [graphics $gr_mol line $prev $coord width $linewidth]
     set prev $coord
     incr count
   }
 } else {
   # constant color
   graphics $gr_mol color $color
   foreach coord $coords {
     lappend gr_list [graphics $gr_mol line $prev $coord width $linewidth]
     set prev $coord
   }
 }

 # return the selection to its original state
 $selection frame $sel_frame
 if {$update} {$selection update}
 return $gr_list
}